# ONLY EDIT /site/etc/csh.cshrc.master
set Z_HOST_SHORT = `uname -n`
set	Z_BSN_DOMAIN	= bsn.com
set	Z_BERKLIX_ORG	= berklix.org
set	Z_FLIP_EP	= film	# gets reset to film-plip for lapl
set	Z_FREEBSD_DOMAIN	= freebsd.org
set	Z_HOLZ_DOMAIN	= js.berklix.net
set	Z_HOLZ_GATE	= gate.${Z_HOLZ_DOMAIN}
set	Z_HOLZ_PLIP_DOMAIN = jhs-plip.private
set	Z_MC_PRI_DOMAIN = mmc.private
set	Z_MC_PUB_DOMAIN = martin-collins.de
set	Z_BERKLIX_JHS	= berklix.net
set	Z_NO_DOMAIN	= no.net
set	Z_VCFE_DOMAIN	= vcfe.org
set	Z_HOST_TYPE	= `uname -s`
set	Z_DHCP_DOMAIN	= dummy_dhcp.org
setenv	HISTORICAL_MAKE_WORLD	yes	# For FreeBSD-5.3-RELEASE
setenv	MAIL_HOST	`hostname`	# default
switch ($Z_HOST_SHORT)		#{
	case deli.${Z_HOLZ_DOMAIN}:
	case dual.${Z_HOLZ_DOMAIN}:
	case film.${Z_HOLZ_DOMAIN}:
	case fire.${Z_HOLZ_DOMAIN}:
	case flat.${Z_HOLZ_DOMAIN}:
	case flip.${Z_HOLZ_DOMAIN}:
	case king.${Z_HOLZ_DOMAIN}:
	case lapa.${Z_HOLZ_DOMAIN}:
	case lapa.${Z_HOLZ_PLIP_DOMAIN}:
	case lapc.${Z_HOLZ_DOMAIN}:
	case lapd.${Z_HOLZ_DOMAIN}:
	case lapl.${Z_HOLZ_DOMAIN}:
	case lapl.${Z_HOLZ_PLIP_DOMAIN}:
	case lapn.${Z_HOLZ_DOMAIN}:
	case lapn.${Z_HOLZ_PLIP_DOMAIN}:
	case laps.${Z_HOLZ_DOMAIN}:
	case loft.${Z_HOLZ_DOMAIN}:
	case mini.${Z_HOLZ_DOMAIN}:
	case lapn.${Z_HOLZ_DOMAIN}:
	case rain.${Z_HOLZ_DOMAIN}:
	case scan.${Z_HOLZ_DOMAIN}:
	case slim.${Z_HOLZ_DOMAIN}:
	case snow.${Z_HOLZ_DOMAIN}:
	case surf.${Z_HOLZ_DOMAIN}:
	case test.${Z_HOLZ_DOMAIN}:
	case thin.${Z_HOLZ_DOMAIN}:
	case towr.${Z_HOLZ_DOMAIN}:
	case wind.${Z_HOLZ_DOMAIN}:
	case wood.${Z_HOLZ_DOMAIN}:
		#{
		setenv	DOMAIN	${Z_HOLZ_DOMAIN}
		setenv	MAIL_HOST	${Z_BERKLIX_JHS}
		set Z_GATE_HOST = ${Z_HOLZ_GATE}
		set Z_FLIP_EP	= flip
		breaksw 	#}
	case mart.${Z_HOLZ_DOMAIN}:
	case park.${Z_HOLZ_DOMAIN}:
		#{
		setenv	DOMAIN	${Z_HOLZ_DOMAIN}
		setenv	MAIL_HOST	${Z_BERKLIX_JHS}
		breaksw 	#}
	case lapa.${Z_DHCP_DOMAIN}:
	case lapc.${Z_DHCP_DOMAIN}:
	case lapd.${Z_DHCP_DOMAIN}:
	case lapl.${Z_DHCP_DOMAIN}:
	case lapn.${Z_DHCP_DOMAIN}:
	case laps.${Z_DHCP_DOMAIN}:
		#{
		setenv	DOMAIN	${Z_DHCP_DOMAIN}
		set nobeep # disable tcsh's terminal beep
		breaksw 	#}
	case lapp.${Z_HOLZ_DOMAIN}:
	case lapp.${Z_HOLZ_PLIP_DOMAIN}:
		#{
		setenv	DOMAIN	${Z_HOLZ_DOMAIN}
		setenv	MAIL_HOST	${Z_BERKLIX_JHS}
		set Z_GATE_HOST = ${Z_HOLZ_GATE}
		set Z_FLIP_EP	= film-plip
		breaksw 	#}
	case cebulon.${Z_BSN_DOMAIN}:
	case test88.${Z_BSN_DOMAIN}:
	case popeye.${Z_BSN_DOMAIN}:
		#{
		# setenv	MAIL_HOST	${Z_BERKLIX_JHS}
		setenv	DOMAIN	${Z_BSN_DOMAIN}
		breaksw 	#}
	case flat.${Z_BERKLIX_ORG}:
	case slim.${Z_BERKLIX_ORG}:
	case thin.${Z_BERKLIX_ORG}:
	case tower.${Z_BERKLIX_ORG}:
		#{
		# setenv	MAIL_HOST	${Z_BERKLIX_JHS}
		setenv	DOMAIN	${Z_BERKLIX_ORG}
		setenv	WWWHOST www.berklix.org
		# WWWHOST needed to over ride FreeBSD-4.7
		# /usr/ports/mail/mailman/work/mailman-2.0.12/
		#	config.status
		#	  s%@FQDN@%bsn.com%g
		#	  s%@URL@%bsd .bsn.com%g
		#	Mailman/Defaults.py
		#	  DEFAULT_HOST_NAME   = 'bsn.com'
		#	  DEFAULT_URL	      = 'http://list.berklix.org/mailman/'
		# presumably the bsd .bsn.com comes from RDNS lookup.
		# If WWWHOST is not set, mailman configure uses MAILHOST.
		breaksw 	#}
	case flop.${Z_MC_PRI_DOMAIN}:
	case frog.${Z_MC_PRI_DOMAIN}:
	case stac.${Z_MC_PRI_DOMAIN}:
		#{
		setenv	DOMAIN		${Z_MC_PRI_DOMAIN}
		setenv MAIL_HOST	${Z_MC_PUB_DOMAIN}
		set Z_GATE_HOST = frog.${Z_MC_PRI_DOMAIN}
		breaksw 	#}
	case freefall.${Z_FREEBSD_DOMAIN}:
	case hub.${Z_FREEBSD_DOMAIN}:
		#{
		setenv	DOMAIN	${Z_FREEBSD_DOMAIN}
		breaksw 	#}
	case symmetric.${Z_VCFE_DOMAIN}:	#{
		setenv	DOMAIN	${Z_VCFE_DOMAIN}
		breaksw 	#}
	case lapa.${Z_NO_DOMAIN}:
	case lapc.${Z_NO_DOMAIN}:
	case lapd.${Z_NO_DOMAIN}:
	case lapl.${Z_NO_DOMAIN}:
	case lapn.${Z_NO_DOMAIN}:
	case laps.${Z_NO_DOMAIN}:
		#{
		setenv	DOMAIN	${Z_NO_DOMAIN}
		breaksw 	#}
	default:		#{
		breaksw 	#}
	endsw	#}
if ($?Z_GATE_HOST) then #{ If Z_GATE_HOST is set, we are a client of that gate.
	setenv	FTPSERVER ${Z_GATE_HOST}
	setenv	ftp_proxy	ftp://${Z_GATE_HOST}:21
	setenv	http_proxy	http://${Z_GATE_HOST}:80
	setenv	FTP_PASSWORD	`whoami`@${MAIL_HOST}
	setenv	FTP_LOGIN	ftp	# overide `fetch` default of anonymous
	# I uncommented FTP_LOGIN 2003.04.02 cos I keep seeing
	# park ftpd[7886]: FTP LOGIN FAILED FROM wind, anonymous@gate
	setenv	all_proxy	http://${Z_GATE_HOST}
	setenv	no_proxy localhost,${DOMAIN}
	else		#}{ We are a gate EG Park
		unsetenv FTP_PASSIVE_MODE
	endif		#}
setenv	GZIP		"--fast"
setenv	SHELL		/bin/csh
setenv	PAGE		A4
setenv	PAPERSIZE	a4	# for ports/ math/R-letter,
setenv	A4		A4	# for generic-4.5/ports/print/ghostscript-gnu
umask 022	# user(owner),group,other rwxrwxrwx thus removes: ---,-w-,-w-
set	Z_MY_HOME		= `cd;pwd`
set	Z_MY_BIN		= $Z_MY_HOME/bin
set	Z_MY_PRIV_BIN	= $Z_MY_HOME/private/bin
set Z_UNAME_R=`uname -r`
setenv	GZIP "--best"
setenv CVSREADONLYFS # man cvs: same as -R read only repository
switch ($Z_HOST_TYPE)	#{
	case FreeBSD:	#{
		limit coredumpsize 0 # prevent core files
		setenv	TZ	GMT-01:00
		setenv	NOCLEANDEPENDS	YES
		set D_D = ""
		set D_D = "$D_D py-mx-base"	# 6.2 loops fetch: ftp://ftp/pub/FreeBSD/dists/7.0-RELEASE//egenix-mx-base-2.0.6.tar.gz: Connection refused
 set D_D = "$D_D itext"	
 set D_D = "$D_D majordomo" # 6.2 install fails & if ports=NFS, lock fails
		setenv DUDS "$D_D"
		setenv FORCE_PACKAGE "Ignore copyright advisory about exporting binaries to others."
			# Cos I''m building packages for my own machines.
		setenv FORCE_PKG_REGISTER "Overwrites in /var/db/pkg/"
		# Even fresh chrrooted build failed when I commented out
		# FORCE_PKG_REGISTER	- because I wanted X built, &
		# imake-6.7.0_2 depends on file: perl5.8.5
		setenv PACKAGEROOT "ftp://ftp"	# Ref man pkg_add
		setenv PORTSDIR /usr/ports
		setenv	HAVE_MOTIF	YES
		setenv	KDEDIR	/usr/local
		setenv	MANPATH '/usr/share/man:/usr/man:/usr/X11R6/man:/usr/local/man:/usr/local/lib/ghostscript/doc:'
		setenv	OPENWINHOME	/usr/X11R6	# what for ?
		setenv	PATH	/sbin:/bin:/usr/sbin:/usr/bin:/usr/games:/usr/local/sbin:/usr/local/bin:/usr/X11R6/bin:$Z_MY_BIN/.other:$Z_MY_BIN/.csh:$Z_MY_BIN/.sh:$Z_MY_PRIV_BIN/.other:$Z_MY_PRIV_BIN/.csh:$Z_MY_PRIV_BIN/.sh:/site/etc/gate:/etc/isdn
		setenv SLRNPULL_ROOT	/var/spool/news/slrn # used by slrnpull
		setenv TMPDIR	~/tmp
		setenv	TZ	Europe/Berlin
		setenv	USA_RESIDENT	NO
		breaksw #}
	case OpenBSD:	#{
		setenv	BSDSRCDIR	`cd /usr/src;pwd`
		setenv	PATH	/sbin:/bin:/usr/sbin:/usr/bin:/usr/X11R6/bin:\
/usr/games:/usr/local/sbin:/usr/local/bin:\
$Z_MY_HOME/bin/.${Z_HOST_TYPE}:$Z_MY_HOME/bin/.csh:$Z_MY_HOME/bin/.sh:\
$Z_MY_HOME/bin/.bash:$Z_MY_HOME/bin/.perl:$Z_MY_HOME/bin/.other
		setenv	TZ	Europe/Berlin
		breaksw #}
	case NetBSD:	#{ surf
		setenv	CFLAGS	"-static -DJULIAN_STACEY -O -I./"
		setenv	LDFLAGS "-static"
		setenv	LINES	56		# for vi
		setenv	MACHINE pc532
		setenv	MACHINE_ARCH	ns32k
		unsetenv	DESTDIR
		setenv	PATH	/sbin:/bin:/usr/sbin:/usr/bin:/usr/gnu/bin:\
/usr/local/bin:/usr/games:$Z_MY_BIN
		breaksw #}
	case Symmetrix: #{ symmetric
		unsetenv	CDPATH
		setenv	GZIP "--best"
		set path=( /sbin /usr/ucb /usr/gnu/bin /bin /usr/bin \
			/usr/local /usr/nsc /usr/bin/misc /usr/vsl/bin ~/bin )
		# SCS /.cshrc: /etc /usr/ucb /bin /usr/bin /usr/local /usr/nsc .
		# SCS /.profile: /etc /usr/ucb /bin /usr/bin /usr/nsc .
		set	cdpath=(/sys \
			/usr/src/{etc,bin,usr.bin,ucb,lib,usr.lib,lib/c,})
		breaksw #}
	case HP-UX:	#{ HP-UX /usr/mail/jhs
		setenv	MANPATH /usr/share/man:/usr/man:/usr/local/man:\
/opt/CC/share/man:`cd ~mayer;pwd`/man
		breaksw #}
	case ULTRIX:	#{
		setenv	PATH	/sbin:/bin:/usr/sbin:/usr/bin:/usr/X11R6/bin:\
/usr/games:/usr/local/sbin:/usr/local/bin:\
$Z_MY_HOME/bin/.${Z_HOST_TYPE}:$Z_MY_HOME/bin/.csh:$Z_MY_HOME/bin/.sh:\
$Z_MY_HOME/bin/.bash:$Z_MY_HOME/bin/.perl:$Z_MY_HOME/bin/.other
		setenv	PATH	$PATH:/usr/bin/X11
		breaksw #}
	case SunOS:	#{
		setenv	PATH /usr/ucb:/bin:/usr/bin:/usr/local/bin
		breaksw #}
	case SCO_SV:	#{ OPS
	case default:	#{
		breaksw #}
	endsw #}
switch ($DOMAIN)	#{ Site Specific Non-Interactive
	case ${Z_HOLZ_DOMAIN}:	#{
		setenv	CVSROOT /usr/cvs
		setenv	CVSROOT_LN /pri/FreeBSD/development/FreeBSD-CVS
		setenv	GS_LIB /usr/local/lib/ghostscript/fonts
		setenv	MAKE_LOCAL
		setenv	MAKE_PORTS
		unsetenv	MAKE_X_MIT
		setenv	MANSEC 1:2:3:4:5:6:7:8:l:n
		setenv	SM_SAVE_DIR	~/dots/private # ref. man 1 xsm
		setenv	XWINFONTPATH	/usr/local/lib/X11/fonts/6x13,/usr/local/lib/X11/fonts/8x13,/usr/local/lib/X11/fonts/25x26,/usr/local/lib/X11/fonts/30x31
		setenv PKG_PATH ftp://ftp.de.netbsd.org/pub/NetBSD/packages/`uname -r`/`uname -m`/All
		breaksw #}
	case ${Z_NO_DOMAIN}:	#{
	case ${Z_VCFE_DOMAIN}:	#{
	case ${Z_BSN_DOMAIN}:	#{
	case ${Z_BERKLIX_ORG}:	#{
		breaksw #}
	case ${Z_MC_PRI_DOMAIN}:	#{
		breaksw #}
	case default:	#{
		breaksw #}
	endsw	#}
if ($?Z_GATE_HOST) then #{
setenv	WWW_HOME http://${Z_GATE_HOST}
	endif		#}
setenv		PKG_TMPDIR /usr/tmp # Some X stuff needs a lot of space.
switch ($Z_HOST_SHORT)	# Host Specific for Interactive {
	case snow.${Z_HOLZ_DOMAIN}: #{
		# if short of space on gate, uncomment next line
		# setenv		PKG_TMPDIR /host/user/usr/tmp
		breaksw #}
	case park.${Z_HOLZ_DOMAIN}:	#{ for ide, not for scsi & mitsumi
		alias xcdplayer "/usr/X11R6/bin/xcdplayer -device /dev/racd0"
		breaksw #}
	case film.${Z_HOLZ_DOMAIN}:	#{
		alias xcdplayer "/usr/X11R6/bin/xcdplayer -device /dev/acd0"
			# on 5.3 volume works finally: mouse to green bar,
			# then for coarse: keep clicking left or right.
			#	for fine middle button & slide
		setenv CDR_DEVICE 1,1,0 	# write device for cdrecord
		breaksw #}
	case fire.${Z_HOLZ_DOMAIN}:	#{
		setenv CDR_SPEED 10		# writer cdrecord
		if ( "x`filetest -c /dev/cd2`" == "x1" ) then #{
			# USB DVDRAM writer exists. Assume it was
			# powered up & connected at boot time when 
			# SCSI allocation occured. (If it was only turned
			# On later,  the allocation assumptions fail.
			# JJLATER investigate devd.conf to improve this.
			setenv CDDA_DEVICE 2,0,0	# reader cdda2wav
			setenv CDR_DEVICE  2,1,0	# writer cdrecord
		else	#}{ USB writer assumed not connected at boot
			setenv CDDA_DEVICE 1,0,0	# reader cdda2wav
			setenv CDR_DEVICE  1,1,0	# writer cdrecord
		endif	#}
		breaksw #}
	case flip.${Z_HOLZ_DOMAIN}:	#{
		setenv CDDA_DEVICE 4,0		# read device for cdda2wav
		breaksw #}
	case rain.${Z_HOLZ_DOMAIN}:	#{
		setenv CDDA_DEVICE 6,0		# read device for cdda2wav
		setenv CDR_DEVICE 6,0		# write device for cdrecord
		setenv CDR_SPEED 2		# write speed for cdrecord
		setenv CDR_FIFOSIZE 8m		# up from 4m.
		breaksw #}
	case wind.${Z_HOLZ_DOMAIN}:	#{
		setenv CDDA_DEVICE 2,0		# read device for cdda2wav
		unsetenv HAVE_MOTIF
		unsetenv KDEDIR
		breaksw #}
	case king.${Z_HOLZ_DOMAIN}:	#{
		setenv CDDA_DEVICE 4,0		# read device for cdda2wav
		setenv CDR_DEVICE 3,0		# write device for cdrecord
		setenv CDR_SPEED 2		# write speed for cdrecord
		setenv CDR_FIFOSIZE 8m		# up from 4m.
		# unsetenv DUDS # fetch all distfiles even if I cant build them.
		unsetenv HAVE_MOTIF
		unsetenv KDEDIR
		breaksw #}
	case laps.${Z_DHCP_DOMAIN}:
	case laps.${Z_HOLZ_DOMAIN}:
	case laps.${Z_NO_DOMAIN}:
		#	CDR_DEVICE   cdrecord
		setenv CDR_DEVICE 0,0,0 # 'HL-DT-ST' 'DVDRAM
		setenv CDR_DEVICE 2,0,0 # 'MATSHITA' 'DVD/CDRW
		# setenv CDR_SPEED   ?		# cdrecord
		setenv CDDA_DEVICE   2,0,0	# cdda2wav
		breaksw #}
	case lapa.${Z_DHCP_DOMAIN}: #{
	case lapc.${Z_DHCP_DOMAIN}:
	case lapl.${Z_DHCP_DOMAIN}:
	case lapn.${Z_DHCP_DOMAIN}:
	case lapd.${Z_DHCP_DOMAIN}:
		setenv NO_CHECKSUM
		breaksw #}
	case freefall.${Z_FREEBSD_DOMAIN}: #{
	case hub.${Z_FREEBSD_DOMAIN}:
		setenv	CVSREAD 		# ~ncvs
		setenv	CVSROOT /home/ncvs
		breaksw #}
	case default:	#{
		breaksw #}
	endsw	#}
if ($?prompt == 0) goto unset_label
setenv	MAILCHECK	10
setenv	EDITOR		vi
setenv	TERMPATH	~/.termcap:/etc/termcap:/usr/share/misc/termcap
set Z_WHOAMI = `who am i | awk '{ print $1 }' | sed -e 's/\\!/ /' | sed -e "s/$Z_HOST_SHORT/ /" | awk '{ print $1 }'`
set autolist yes # print expansion alternatives on filename tab-completion
set	history 	= 100
alias	a		'alias | more'
alias	c		'cls;cd;jobs'
alias	coax		'cd /site/domain/this/etc/namedb/master;vi *.fwd'
alias	df		'df -H -t ufs,msdosfs'
alias	fmt		"/usr/bin/fmt 70 75"
alias	h		"history | tail -20"
alias	ispell		"/usr/local/bin/ispell -x"
alias	isdn		"/etc/isdn/isdn"
alias	j		jobs -l
alias	k		ksmp3play
alias	l		"ls -al"
alias	ll		ls -lg
alias	ls		"ls -F"
alias	mf		"mformat -t 80 -h 2 -s 18 a:"
alias	n		"cd ~/txt/notes ; make notes.vhtml"
alias	oo		"echo 'Caution NFS eould fail';openoffice"
alias	p		"ps -laxwwh"
alias	pd		pushd
alias	pe		"printenv | sort | more"
alias	po		popd
alias	rd		rmdir
alias	rewind		'(cd /dev ; dd if=tape of=null count=1 ; dd if=tape of=null count=1 )'
alias	skip		"dd if=/dev/ntape of=/dev/null"
alias	sl		'ls | rev | sort | rev | more'
alias	slrn		"/usr/local/bin/slrn -f ~/dots/slrn/.jnewsrc"
alias	spell		"spell -b"
if ($Z_HOST_TYPE != Symmetrix) then	#{	Symmetrix old, has no ssh.
 alias	telnet		"echo Use ssh when possible.; /usr/bin/telnet $*"
 alias	rlogin		"echo Use ssh when possible.; /usr/bin/rlogin $*"
endif					#}
alias	names		"vi ~/job/odd/names"
alias	people		"vi ~/txt/text/people"
alias	urls		"vi ~/txt/text/urls"
set	filec	# escape completes names
setenv	BLOCKSIZE	K
if ( X.$Z_HOST_TYPE == X.SCO_SV) then	#{
	stty -a > /dev/null
	endif				#}
stty	eof '^d' erase '^h' intr '^c' kill '^u' susp '^z'
set prompt="%B`echo $Z_UNAME_R | sed -e s/-RELEASE//` `tty | sed -e s/\\/dev\\/tty//` $Z_WHOAMI ! %m%~ %b"
switch ($Z_HOST_TYPE)	#{ Generic (select by $Z_HOST_TYPE later)
	case FreeBSD:	#{
		# set prompt="%B$Z_WHOAMI@%m `echo $Z_UNAME_R | sed -e s/-RELEASE//` `tty | sed -e s/\\/dev\\/tty//` %~ ! %b"
		#	jhs@fire 5.3 p3 /usr/tmp 2
		set prompt="%B`echo $Z_UNAME_R | sed -e s/-RELEASE//` `tty | sed -e s/\\/dev\\/tty//` $Z_WHOAMI ! %m%~ %b"
		# New prompt easier to mouse to a /host/something for cd, eg: # 5.3 p3 2 fire/usr/tmp
		alias xlock "xlock -mode mountain"
		setenv	TTY_SETS	`stty -g` # ; export TTY_SETS
		setenv	XKEYSYMDB /usr/X11R6/lib/X11/XKeysymDB	# For netscape
		setenv	XNLSPATH	/usr/X11R6/lib/X11/nls	# For netscape
		setenv	SPUNK_COLOR	YES	# for xestic
		setenv	SPUNK_LANGUAGE	2 # for xestic, 1=German, 2=English
		setenv	SPUNK_COUNTRY 049
		setenv	SPUNK_XFONT	12x24	# or 8x13
		alias xestic \
		 "cd /etc/pbx; xestic -display disp:0.0"
		breaksw #}
	case Symmetrix: #{
		set prompt="$Z_WHOAMI@$Z_HOST_SHORT csh `tty | sed -e s/\\/dev\\///` ! % "
		alias	date	'date -u'
		alias	df	/bin/df -i
		breaksw #}
	case OpenBSD:	#{
		alias	eject "/bin/eject /dev/rfd0c"
		alias	swapinfo	"pstat -s"
		breaksw #}
	case NetBSD:	#{
		alias	5	echo You are already on $Z_HOST_SHORT
		alias	b	kermit -l /dev/tty06 -b 9600 -c
		alias	s	kermit -l /dev/tty05 -b 9600 -c
		setenv	DOC	dummy_to_stop_make_clean_of_share_doc_aborting
		setenv	TERM vt_100_l56
		setenv	TERMCAP "vt_100_l56:bl=^G:cr=^M:it#8:do=^J:co#80:li#56:cl=50\E[;H\E[2J:sf=2*\ED:le=^H:bs:am:cm=5\E[%i%d;%dH:nd=2\E[C:up=2\E[A:cb=3\E[1K:ce=3\E[K:cd=50\E[J:so=2\E[7m:se=2\E[m:us=2\E[4m:ue=2\E[m:md=2\E[1m:mr=2\E[7m:mb=2\E[5m:me=2\E[m:is=\E[1;24r\E[24;1H:if=/usr/share/tabset/vt100:rs=\E>\E[?3l\E[?4l\E[?5l\E[?7h\E[?8h:ks=\E[?1h\E=:ke=\E[?1l\E>:ku=\EOA:kd=\EOB:kr=\EOC:kl=\EOD:kb=^H:ho=\E[H:k1=\EOP:k2=\EOQ:k3=\EOR:k4=\EOS:pt:sr=2*\EM:vt#3:xn:sc=\E7:rc=\E8:cs=\E[%i%d;%dr:"
		setenv	TTY_SETS	`stty -g` # ; export TTY_SETS
		breaksw #}
	case SCO_SV:	#{
		alias resize '/usr/bin/X11/resize|egrep \'(LINES|COLUMNS)\' >! ~/.resize; source ~/.resize; rm ~/.resize'
		alias rsh rcmd	# SCO rsh is the restricted shell,
		breaksw #}
	case default:	#{
		echo "/etc/csh.cshrc 2nd switch: no action for $Z_HOST_SHORT"
		breaksw #}
	endsw	#}
switch ($DOMAIN)	#{ Site Specific
	case ${Z_HOLZ_DOMAIN}: #{
		setenv	ARCHIE_HOST	archie.th-darmstadt.de # what muc use
		setenv	NNTPSERVER	news.muc.de
		breaksw #}
	case ${Z_MC_PRI_DOMAIN}:	#{
		breaksw #}
	case ${Z_FREEBSD_DOMAIN}: #{
		echo "Suggest: who ; cvs hi -a"
		echo "CVSREAD=$CVSREAD CVSROOT=$CVSROOT"
		breaksw #}
	case default:	#{
		breaksw #}
	endsw	#}
unset_label:
unset \
	Z_BERKLIX_JHS		\
	Z_BERKLIX_ORG		\
	Z_BSN_DOMAIN		\
	Z_DHCP_DOMAIN		\
	Z_FLIP_EP		\
	Z_FREEBSD_DOMAIN	\
	Z_GATE_HOST		\
	Z_HOLZ_DOMAIN		\
	Z_HOLZ_GATE		\
	Z_HOLZ_PLIP_DOMAIN	\
	Z_HOST_SHORT		\
	Z_HOST_TYPE		\
	Z_MC_PRI_DOMAIN 	\
	Z_MC_PUB_DOMAIN 	\
	Z_MY_BIN		\
	Z_MY_HOME		\
	Z_MY_PRIV_BIN		\
	Z_NO_DOMAIN		\
	Z_UNAME_R		\
	Z_VCFE_DOMAIN		\
	Z_WHOAMI